AdobeTURK

[g_azlag]

Merhaba arkadaşlar,
Elimde 10 tane resim var (resim1, resim2,...) bu resimleri 10 ar sn aralıklarla değiştirmek isitiyorum.

veya resimler rasgele olarakta gelebilir

Bunu nasıl yapabilirim?

[g_azlag]

yaptım arkadaşlar

Kod: Tümünü seç

global gelecekResim

property spriteNum

on prepareFrame
  if gelecekResim = "" then gelecekResim = 1
 
  zaman = the timer
  if (zaman mod 300 = 0) then
   put zaman
    gelecekResim_aynimi = gelecekResim
    gelecekResim = random(18)
    if gelecekResim_aynimi = gelecekResim then gelecekResim = random(18)
  end if
 
  DegisResim1 = "sponsor" & gelecekResim
 
  if gelecekResim <> VOID then
    sprite(11).member = member(DegisResim1)
  end if
end

[/code][/quote]

[eldemir]

http://www.eldemir.net/files/genel/rasgeleResim.zip

buraya bir ornek hazirlayip koydum. daha karisik yada daha da basit yazilabilir.

Kapadokya'da cektigim resimleri koydum icine iyi seyirler.

Not : Director MX 2004 dosyasidir.

Kod: Tümünü seç

-- Emre ELDEMIR
-- Mayis 2007
-- ////////////

property pZaman
property pAralik
property pResimListesi
property pSira

-- sprite ile basladiginda
on beginsprite me
  -- resimlerin isimleri
  pResimListesi = ["IMG_0003", "IMG_0019", "IMG_0065", "IMG_0037", "IMG_0025", "IMG_0035", "IMG_0043", "IMG_0042", "IMG_0032", "IMG_0315"]
 
  -- milisaniye olarak suremiz
  pZaman = the milliseconds
 
  -- kac sn'de ye bir resim degisecek??
  pAralik = 2 --2 sn'de bir..
 
  -- kacinci resimdeyiz..!!!
  pSira = 1
end


--  //resimlerin isimlerini yukardaki listeye aktarabilmek icin kullandim daha sonrada silmedim :)
--  repeat with i=1 to 10
--    pResimListesi.add(member(i).name)
--  end repeat
--  put pResimListesi
-- //siz isterseniz buraya random olarak siralatabilirsiniz.


on exitFrame me
 
  if (the milliseconds-pZaman) > (pAralik*1000) then
   
    pZaman = the milliseconds
   
    if pSira <10 then
      pSira = pSira +1
      sprite(me.spriteNum).member = member(pResimListesi[pSira])
    else
      --  10 tane resim ekranda gosterildi.. simdi ne olacak?
      --    eger bastan baslasin diyorsan
      --
      --        pSira = 1
      --        pZaman = the milliseconds
    end if
   
  end if
 
end


[eldemir]

yada daha kisa yolu

Kod: Tümünü seç

-- Emre ELDEMIR
-- Mayis 2007
-- ////////////

property pResimListesi
property pSira

-- sprite ile basladiginda
on beginsprite me
  -- resimlerin isimleri
  pResimListesi = ["IMG_0003", "IMG_0019", "IMG_0065", "IMG_0037", "IMG_0025", "IMG_0035", "IMG_0043", "IMG_0042", "IMG_0032", "IMG_0315"]
 
  -- kacinci resimdeyiz..!!!
  pSira = 1
  --2 sn'de degistir fonksiyonunu calistir...!
  timeOut().new("timer1",2000, #degistir,me)

end


on degistir me

    if pSira <10 then
      pSira = pSira +1
      sprite(me.spriteNum).member = member(pResimListesi[pSira])
    else
      --  10 tane resim ekranda gosterildi.. simdi ne olacak?
      --    eger bastan baslasin diyorsan
      --
      --        pSira = 1

    end if

end

[eldemir]

Rasgele resimleri siralayan versiyonu..bir gosterdigini bir daha gostermiyor.

Kod: Tümünü seç

-- Emre ELDEMIR
-- Mayis 2007
-- ////////////

property pResimListesi
property pSira
property pList
property pToplam

-- sprite ile basladiginda
on beginsprite me
  -- resimlerin isimleri
  pResimListesi = ["IMG_0003", "IMG_0019", "IMG_0065", "IMG_0037", "IMG_0025", "IMG_0035", "IMG_0043", "IMG_0042", "IMG_0032", "IMG_0315"]
  pToplam = pResimListesi.count
 
  -- kacinci resimdeyiz..!!!
  pSira = 1
 
  rasgele(me)
 
  timeOut().new("timer1",2000, #degistir,me)
 
end

on degistir me
 
    if pSira < pToplam then
      pSira = pSira +1
      sprite(me.spriteNum).member = member(pResimListesi[pList[pSira]])
    else
      --  10 tane resim ekranda gosterildi.. simdi ne olacak?
      --    eger bastan baslasin diyorsan
      --
      --    pSira = 1   
      --    rasgele(me)   
    end if
 
end


on rasgele me
   
  tempList = [] -- icinde sirali rakamlar var
  pList    = [] -- rakamlarin sirasi degistiriliyor
 
  repeat with i=1 to pToplam
    tempList.add(i)
  end repeat
 
  repeat with i=1 to pToplam
    sayi = random(integer(tempList.count))
    pList.add(tempList[sayi])
    tempList.deleteAt(sayi)
  end repeat
 
  put pList && "<< tList"

end